DECLARE @name VARCHAR(50) -- Database name 
DECLARE @path VARCHAR(256) -- Path for backup files 
DECLARE @fileName VARCHAR(256) -- Filename for backup 
DECLARE @fileDate VARCHAR(20) -- Used for file name 

-- Specify database backup directory 
SET @path = 'D:\MyBackupFolder\' 
exec master.dbo.xp_create_subdir @path 

-- Specify the filename format
SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),112) 

DECLARE db_cursor CURSOR FOR 
SELECT name 
FROM master.dbo.sysdatabases 
WHERE name IN ('MyDatabase1','MyDatabase2','MyDatabase3', 'MyDatabase4') -- Add the names of all database you want to backup

OPEN db_cursor 
FETCH NEXT FROM db_cursor INTO @name 

WHILE @@FETCH_STATUS = 0 
BEGIN 
SET @fileName = @path + @name + '_' + @fileDate + '.BAK' 
BACKUP DATABASE @name TO DISK = @fileName 

FETCH NEXT FROM db_cursor INTO @name 
END 

CLOSE db_cursor 
DEALLOCATE db_cursor