Initial commit

BackupMultipleDatabases.sql

@@ -0,0 +1,30 @@
+DECLARE @name VARCHAR(50) -- Database name 
+DECLARE @path VARCHAR(256) -- Path for backup files 
+DECLARE @fileName VARCHAR(256) -- Filename for backup 
+DECLARE @fileDate VARCHAR(20) -- Used for file name 
+
+-- Specify database backup directory 
+SET @path = 'D:\MyBackupFolder\' 
+exec master.dbo.xp_create_subdir @path 
+
+-- Specify the filename format
+SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),112) 
+
+DECLARE db_cursor CURSOR FOR 
+SELECT name 
+FROM master.dbo.sysdatabases 
+WHERE name IN ('MyDatabase1','MyDatabase2','MyDatabase3', 'MyDatabase4') -- Add the names of all database you want to backup
+
+OPEN db_cursor 
+FETCH NEXT FROM db_cursor INTO @name 
+
+WHILE @@FETCH_STATUS = 0 
+BEGIN 
+SET @fileName = @path + @name + '_' + @fileDate + '.BAK' 
+BACKUP DATABASE @name TO DISK = @fileName 
+
+FETCH NEXT FROM db_cursor INTO @name 
+END 
+
+CLOSE db_cursor 
+DEALLOCATE db_cursor

PrintTableColumnDefinitions.sql

@@ -0,0 +1,23 @@
+USE [MY_DATABASE_NAME]
+
+SELECT
+sh.name+'.'+o.name AS ObjectName,
+s.name as ColumnName
+,CASE
+    WHEN t.name IN ('char','varchar') THEN t.name+'('+CASE WHEN s.max_length<0 then 'MAX' ELSE CONVERT(varchar(10),s.max_length) END+')'
+	WHEN t.name IN ('nvarchar','nchar') THEN t.name+'('+CASE WHEN s.max_length<0 then 'MAX' ELSE CONVERT(varchar(10),s.max_length/2) END+')'
+	WHEN t.name IN ('numeric') THEN t.name+'('+CONVERT(varchar(10),s.precision)+','+CONVERT(varchar(10),s.scale)+')'
+	ELSE t.name
+END AS DataType
+,CASE
+	 WHEN s.is_nullable=1 THEN 'NULL'
+	ELSE 'NOT NULL'
+END AS Nullable       
+	
+FROM sys.columns s
+INNER JOIN sys.types t ON s.system_type_id=t.user_type_id and t.is_user_defined=0
+INNER JOIN sys.objects o ON s.object_id=o.object_id
+INNER JOIN sys.schemas sh on o.schema_id=sh.schema_id
+WHERE O.name IN
+   (select table_name from information_schema.tables) 
+ORDER BY sh.name+'.'+o.name,s.column_id

SearchAllTables.sql

@@ -0,0 +1,67 @@
+DECLARE @SearchStr nvarchar(100)
+SET @SearchStr = '## YOUR STRING HERE ##'
+
+
+    -- Copyright © 2002 Narayana Vyas Kondreddi. All rights reserved.
+    -- Purpose: To search all columns of all tables for a given search string
+    -- Written by: Narayana Vyas Kondreddi
+    -- Site: http://vyaskn.tripod.com
+    -- Updated and tested by Tim Gaunt
+    -- http://www.thesitedoctor.co.uk
+    -- http://blogs.thesitedoctor.co.uk/tim/2010/02/19/Search+Every+Table+And+Field+In+A+SQL+Server+Database+Updated.aspx
+    -- Tested on: SQL Server 7.0, SQL Server 2000, SQL Server 2005 and SQL Server 2010
+    -- Date modified: 03rd March 2011 19:00 GMT
+    CREATE TABLE #Results (ColumnName nvarchar(370), ColumnValue nvarchar(3630))
+
+    SET NOCOUNT ON
+
+    DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110)
+    SET  @TableName = ''
+    SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')
+
+    WHILE @TableName IS NOT NULL
+    
+    BEGIN
+        SET @ColumnName = ''
+        SET @TableName = 
+        (
+            SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
+            FROM     INFORMATION_SCHEMA.TABLES
+            WHERE         TABLE_TYPE = 'BASE TABLE'
+                AND    QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
+                AND    OBJECTPROPERTY(
+                        OBJECT_ID(
+                            QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
+                             ), 'IsMSShipped'
+                               ) = 0
+        )
+
+        WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
+            
+        BEGIN
+            SET @ColumnName =
+            (
+                SELECT MIN(QUOTENAME(COLUMN_NAME))
+                FROM     INFORMATION_SCHEMA.COLUMNS
+                WHERE         TABLE_SCHEMA    = PARSENAME(@TableName, 2)
+                    AND    TABLE_NAME    = PARSENAME(@TableName, 1)
+                    AND    DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar', 'int', 'decimal')
+                    AND    QUOTENAME(COLUMN_NAME) > @ColumnName
+            )
+    
+            IF @ColumnName IS NOT NULL
+            
+            BEGIN
+                INSERT INTO #Results
+                EXEC
+                (
+                    'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) FROM ' + @TableName + ' (NOLOCK) ' +
+                    ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
+                )
+            END
+        END    
+    END
+
+    SELECT ColumnName, ColumnValue FROM #Results
+
+DROP TABLE #Results

ShrinkLogFiles.sql

@@ -0,0 +1,21 @@
+DECLARE @logName as nvarchar(50)
+DECLARE @databaseID as int
+DECLARE db_cursor CURSOR FOR 
+SELECT TOP 10 name,database_id -- only 10 but you can choose any number 
+FROM sys.master_Files WHERE physical_name like '%.ldf'
+--and physical_name not like 'C:\%'  -- specify your database paths 
+and name not in ('mastlog','MSDBLog','templog','modellog','_LogFiles_log','MSDBLog') -- any database logs that you would like to exclude 
+ORDER BY size DESC
+OPEN db_cursor 
+FETCH NEXT FROM db_cursor INTO @logName , @databaseID
+WHILE @@FETCH_STATUS = 0 
+BEGIN 
+    DECLARE @databaseName as nvarchar(50)
+ SET @databaseName =  DB_NAME(@databaseID)
+  DECLARE @tsql nvarchar(300)
+ SET @tsql='USE ['+@databaseName+'] ALTER DATABASE ['+@databaseName+'] set recovery simple DBCC SHRINKFILE ('+@logName+' , 1)'
+ EXEC(@tsql)
+    FETCH NEXT FROM db_cursor INTO @logName , @databaseID
+END 
+CLOSE db_cursor
+DEALLOCATE db_cursor